home *** CD-ROM | disk | FTP | other *** search
/ Aminet 22 / Aminet 22 (1997)(GTI - Schatztruhe)[!][Dec 1997].iso / Aminet / comm / term / AmiTEL310.lha / AmiTEL.install < prev    next >
Text File  |  1997-08-28  |  14KB  |  478 lines
  1. ;*******************************************;
  2. ;                                           ;
  3. ; $VER: AmiTEL installation v3.1 (28/08/97) ;
  4. ;                                           ;
  5. ;    Script Installer for AmiTEL.        ;
  6. ;                                           ;
  7. ;            © 1992-1997 Ldfa.              ;
  8. ;                                           ;
  9. ;*******************************************;
  10.  
  11. (complete 0)
  12.  
  13. ;
  14. ; Initialisations.
  15. ;
  16.  
  17. (set @app-name "AmiTEL")
  18.  
  19. ; Locale strings.
  20.  
  21. (if (= @language "français")
  22.   (
  23.     (set default-guide "AmiTEL.guide")
  24.     (set #bad-kick  (cat "\nAmiTEL ne fonctionne qu'avec un KickStart 2.04+."))
  25.     (set #bad-level (cat "\nL'installation d'AmiTEL nécessite au moins le niveau 'EXPERT'. "
  26.                          "Relancez l'installation et selectionnez un niveau approprié.\n"))
  27.     (set #intro     (cat "Bienvenue sur le programme d'installation d'AmiTEL "
  28.                          "v3.1. Cette installation utilise le programme "
  29.                          "'Installer' de Commodore pour les ordinateurs Amiga.\n"))
  30.     (set #dest-dir  (cat "\nSélectionnez une unité dans laquelle sera crée le "
  31.                          "répertoire AmiTEL.\n"))
  32.     (set #dest-help (cat "\nLe répertoire 'AmiTEL' qui va être crée contiendra tous les "
  33.                          "fichiers nécessaires au bon fonctionnement du programme.\n"))
  34.     (set #make-dir  (cat "\nVoulez vous créer le répertoire 'AmiTEL' ?\n"))
  35.     (set #prg-file  (cat "\nSelectionnez les programmes a installer :\n"))
  36.     (set #prg-help  (cat "\n'AmiTEL' est le programme principal de l'application, "
  37.                          "'Amigatel_w3' est un script Arexx de connexion à Amigatel via Internet, "
  38.                          "'Update' permet de mettre à jour le fichier 'AmiTEL.phone' "
  39.                          "s'il a été crée avec une version d'AmiTEL < 2.0.\n"))
  40.     (set #ex-file   (cat "\nVoulez vous installer les fichiers d'exemples d'AmiTEL ?\n"))
  41.     (set #ex-help   (cat "\n'Exemple.vdt' est un fichier d'exemple au format Videotex "
  42.                          "et 'Example.pst' est un fichier d'exemple au format Prestel.\n"))
  43.     (set #sel-file  (cat "\nSelectionnez le fichier à installer :\n"))
  44.     (set #key-file  (cat "\nVoulez vous installer votre clé d'enregistrement ?\n"))
  45.     (set #key-help  (cat "\nVotre clé d'enregistrement est personnelle. Elle permet de "
  46.                          "débloquer les fonctions qui ne sont pas disponibles dans la "
  47.                          "version de démonstration.\n"))
  48.     (set #old-cfg   (cat "\nVoulez vous supprimer le fichier 'S:AmiTEL.cfg' obsolète ?\n"))
  49.     (set #old-font  (cat "\nVoulez vous supprimer les fontes Minitel obsolètes ?\n"))
  50.     (set #old-bbt   (cat "\nVoulez vous supprimer le fichier 'BBTPro' obsolètes ?\n"))
  51.     (set #old-help  (cat "\nLes fichiers 'BBTPro', 'S:AmiTEL.cfg' et les fontes Minitel"
  52.                          " sont obsolètes.\n"))
  53.     (set #doc-file  (cat "\nVoulez vous installer la documentation d'AmiTEL ?\n"))
  54.     (set #doc-help  (cat "\nLa documentation d'AmiTEL doit être installée dans le même "
  55.                          "répertoire que le programme principal pour bénéficier de "
  56.                          "l'aide en ligne.\n"))
  57.     (set #rexx-file (cat "\nVoulez vous installer les fichiers script ARexx ?\n"))
  58.     (set #rexx-help (cat "\nLes exemples de script ARexx vous permettrons de découvrir toutes "
  59.                          "les potentialités des commandes ARexx d'AmiTEL. Vous devez "
  60.                          "obligatoirement les installer dans le répertoire 'REXX:'.\n"))
  61.     (set #xpr-lib   (cat "\nVoulez vous installer les protocoles de téléchargement XPR ?\n"))
  62.     (set #xpr-help  (cat "\nLes protocoles de téléchargement XPR permettent de télécharger "
  63.                          "des programmes sur les serveurs Amiga sans avoir à utiliser des "
  64.                          "programmes externes.\n"))
  65.     (set #020-lib   (cat "\nVoulez vous installer les versions pour micro-processeurs 020/030/040 ?\n"))
  66.     (set #020-help  (cat "\nSi vous possédé un micro-processeur 020, 030 ou 040, vous pouvez "
  67.                          "installer les versions spécialement compilées pour ceux-ci.\n"))
  68.     (set #bbt-lib   (cat "\nVoulez vous copier la librairie XPRBBTPro dans LIBS: ?\n"))
  69.     (set #moon-lib  (cat "\nVoulez vous copier la librairie XPRMoondial dans LIBS: ?\n"))
  70.     (set #req-lib   (cat "\nVoulez vous copier la librairie ReqTools dans LIBS: ?\n"))
  71.     (set #odu-lib   (cat "\nVoulez vous copier la librairie OwnDevUnit dans LIBS: ?\n"))
  72.     (set #update    (cat "\n\nIMPORTANT\n\n"
  73.                          "N'oubliez pas de mettre à jour votre fichier\n"
  74.                          "'AmiTEL.phone' en utlisant le commande 'Update'\n"
  75.                          "si votre ancienne version est < à 2.0 uniquement.\n"))
  76.   )
  77.   (
  78.     (set default-guide "AmiTEL.English.guide")
  79.     (set #bad-kick  (cat "\nAmiTEL works only with 2.04+ kickstart."))
  80.     (set #bad-level (cat "\nAmiTEL installation requires at least the 'EXPERT' user level. "
  81.                          "Restart installation and select appropriate user level.\n"))
  82.     (set #intro     (cat "Welcome on the AmiTEL v3.1 installation program. "
  83.                          "This installation use Commodore 'Installer' "
  84.                          "program for the Amiga Computer.\n"))
  85.     (set #dest-dir  (cat "\nSelect the destination drawer where AmiTEL "
  86.                          "directory must be created.\n"))
  87.     (set #dest-help (cat "\n'AmiTEL' drawer which will be created will hold all necessary "
  88.                          "files for this application.\n"))
  89.     (set #make-dir  (cat "\nDo you want to create the 'AmiTEL' drawer ?\n"))
  90.     (set #prg-file  (cat "\nSelect program files to install :\n"))
  91.     (set #prg-help  (cat "\n'AmiTEL' is the main application program, "
  92.                          "'Amigatel_w3' is an Arexx script of Amigatel connexion via Internet, "
  93.                          "'Update' allow to upgrade 'AmiTEL.phone' file "
  94.                          "from old AmiTEL version < 2.0.\n"))
  95.     (set #ex-file   (cat "\nDo you want to install AmiTEL examples files ?\n"))
  96.     (set #ex-help   (cat "\n'Exemple.vdt is a Videotext example file and"
  97.                          " Example.pst is a Prestel example file.\n"))
  98.     (set #sel-file  (cat "\nSelect file to install :\n"))
  99.     (set #key-file  (cat "\nDo you want to install your registation keyfile ?\n"))
  100.     (set #key-help  (cat "\nYour registered key is personal. it give at your "
  101.                          "program all these functionality.\n"))
  102.     (set #old-cfg   (cat "\nDo you want to delete the old 'S:AmiTEL.cfg' file ?\n"))
  103.     (set #old-bbt   (cat "\nDo you want to delete the old 'BBTPro' file ?\n"))
  104.     (set #old-font  (cat "\nDo you want to delete the old Minitel fonts ?\n"))
  105.     (set #old-help  (cat "\n'BBTPro', 'S:AmiTEL.cfg' files and Minitel fontes are out of date.\n"))
  106.     (set #doc-file  (cat "\nDo you want to install AmiTEL documentation ?\n"))
  107.     (set #doc-help  (cat "\nAmiTEL documentation must be installed in the same drawer "
  108.                          "than the main program to have online help possibility.\n"))
  109.     (set #cat-file  (cat "\nDo you want to install english catalogue file ?\n"))
  110.     (set #cat-help  (cat "\nEnglish catalogue file permit to have all text in english.\n"))
  111.     (set #rexx-file (cat "\nDo you want to install ARexx script files ?\n"))
  112.     (set #rexx-help (cat "\nSome ARexx script files permit to show you all powerfull "
  113.                          "AmiTEL ARexx commands. You must installed them in 'REXX:' drawer.\n"))
  114.     (set #xpr-lib   (cat "\nDo you want to install XPR transfer protocols ?\n"))
  115.     (set #xpr-help  (cat "\nXPR transfer protocol permit transfert without external "
  116.                          "program needed.\n"))
  117.     (set #020-lib   (cat "\nDo you want to install 020/030 versions ?\n"))
  118.     (set #020-help  (cat "\nIf you have a 020, 030 or 040 processor, you can to "
  119.                          "installe compiled versions for us.\n"))
  120.     (set #bbt-lib   (cat "\nDo you want to copy XPRBBTPro library in LIBS: ?\n"))
  121.     (set #moon-lib  (cat "\nDo you want to copy XPRMoondial library in LIBS: ?\n"))
  122.     (set #req-lib   (cat "\nDo you want to copy ReqTools library in LIBS: ?\n"))
  123.     (set #odu-lib   (cat "\nDo you want to copy OwnDevUnit library in LIBS: ?\n"))
  124.     (set #update    (cat "\n\nWARNING\n\n"
  125.                          "Don't forget to update your 'AmiTEL.phone' file with\n"
  126.                          "'update' program only if your old version was < 2.0.\n"))
  127.   )
  128. )
  129.  
  130. ; Welcome message.
  131.  
  132. (welcome #intro)
  133.  
  134. ; Test KickStart 2.04+.
  135.  
  136. (if (< (/ (getversion) 65536) 37)
  137.   (abort #bad-kick)
  138. )
  139.  
  140. (if (< @user-level 2)
  141.   (abort #bad-level)
  142. )
  143.  
  144. ; Copy AmiTEL programs and documentation.
  145.  
  146. (set Path.Source (expandpath (pathonly @icon)))
  147.  
  148. (set Path.Dest
  149.   (tackon
  150.     (askdir
  151.       (prompt #dest-dir)
  152.       (help #dest-help)
  153.       (default "WORK:")
  154.     )
  155.     "AmiTEL"
  156.   )
  157. )
  158.  
  159. (makedir Path.Dest
  160.   (prompt #make-dir)
  161.   (help @makedir-help)
  162.   (infos)
  163.   (confirm)
  164. )
  165.  
  166. (copyfiles
  167.   (prompt #prg-file)
  168.   (help #prg-help)
  169.   (source Path.Source)
  170.   (dest   Path.Dest)
  171.   (choices "AmiTEL"
  172.            "Amigatel_w3"
  173.            "Update")
  174.   (infos)
  175.   (confirm)
  176. )
  177.  
  178. (complete 10)
  179.  
  180. ; Copy 'Exemple.vdt' and 'Example.pst' files.
  181.  
  182. (if
  183.   (exists "Exemple.vdt")
  184.   (if
  185.     (askbool
  186.       (prompt #ex-file)
  187.       (help #ex-help)
  188.       (default 1)
  189.     )
  190.  
  191.     (
  192.       (copyfiles
  193.         (prompt #sel-file)
  194.         (help @copyfiles-help)
  195.         (source Path.Source)
  196.         (dest   Path.Dest)
  197.         (choices "Exemple.vdt"
  198.                  "Example.pst")
  199.         (confirm)
  200.       )
  201.     )
  202.   )
  203. )
  204.  
  205. (complete 20)
  206.  
  207. ; Copy 'AmiTEL.key' file.
  208.  
  209. (if
  210.   (exists "L/AmiTEL.key")
  211.   (if
  212.     (askbool
  213.       (prompt #key-file)
  214.       (help #key-help)
  215.       (default 1)
  216.     )
  217.  
  218.     (
  219.       (copyfiles
  220.         (prompt #sel-file)
  221.         (help @copyfiles-help)
  222.         (source "L")
  223.         (dest   "L:")
  224.         (choices "AmiTEL.key")
  225.         (confirm)
  226.       )
  227.     )
  228.   )
  229. )
  230.  
  231. (complete 30)
  232.  
  233. ; Delete old 'AmiTEL.cfg', 'BBTPro' and fonts.
  234.  
  235. (if
  236.   (exists "S:AmiTEL.cfg")
  237.   (if
  238.     (askbool
  239.       (prompt #old-cfg)
  240.       (help #old-help)
  241.       (default 1)
  242.     )
  243.  
  244.     (
  245.       (delete "S:AmiTEL.cfg")
  246.     )
  247.   )
  248. )
  249.  
  250. (if
  251.   (exists "BBTPro")
  252.   (if
  253.     (askbool
  254.       (prompt #old-bbt)
  255.       (help #old-help)
  256.       (default 1)
  257.     )
  258.  
  259.     (
  260.       (delete "BBTPro")
  261.     )
  262.   )
  263. )
  264.  
  265. (if
  266.   (exists "FONTS:Minitel")
  267.   (if
  268.     (askbool
  269.       (prompt #old-font)
  270.       (help #old-help)
  271.       (default 1)
  272.     )
  273.  
  274.     (
  275.       (delete "Fonts:Minitel/8")
  276.       (delete "Fonts:Minitel/16")
  277.       (delete "Fonts:Minitel")
  278.       (delete "Fonts:Minitel.font")
  279.       (delete "Fonts:Minitel16/8")
  280.       (delete "Fonts:Minitel16/16")
  281.       (delete "Fonts:Minitel16")
  282.       (delete "Fonts:Minitel16.font")
  283.       (delete "Fonts:Minitel80/8")
  284.       (delete "Fonts:Minitel80")
  285.       (delete "Fonts:Minitel80.font")
  286.     )
  287.   )
  288. )
  289.  
  290. (complete 40)
  291.  
  292. ; Copy 'AmiTEL.guide', 'XPRBBTPro.guide' et 'XPRMoonDial.guide' files.
  293.  
  294. (if
  295.   (askbool
  296.     (prompt #doc-file)
  297.     (help #doc-help)
  298.     (default 1)
  299.   )
  300.  
  301.   (
  302.     (copyfiles
  303.       (prompt #sel-file)
  304.       (help @copyfiles-help)
  305.       (source Path.Source)
  306.       (dest   Path.Dest)
  307.       (choices default-guide)
  308.       (newname "AmiTEL.guide")
  309.       (infos)
  310.       (confirm)
  311.     )
  312.  
  313.     (copyfiles
  314.       (prompt #sel-file)
  315.       (help @copyfiles-help)
  316.       (source Path.Source)
  317.       (dest   Path.Dest)
  318.       (choices "XPRBBTPro.guide"
  319.                "XPRMoonDial.guide")
  320.       (infos)
  321.       (confirm)
  322.     )
  323.   )
  324. )
  325.  
  326. (complete 50)
  327.  
  328. ; Copy 'AmiTEL.catalog' file.
  329.  
  330. (if (= @language "english")
  331.   (if
  332.     (askbool
  333.       (prompt #cat-file)
  334.       (help #cat-help)
  335.       (default 1)
  336.     )
  337.  
  338.     (
  339.       (copyfiles
  340.         (prompt #sel-file)
  341.         (help @copyfiles-help)
  342.         (source Path.Source)
  343.         (dest   Path.Dest)
  344.         (choices "AmiTEL_Prestel.macros")
  345.         (confirm)
  346.       )
  347.     )
  348.  
  349.     (
  350.       (copyfiles
  351.         (prompt #sel-file)
  352.         (help @copyfiles-help)
  353.         (source "Locale/Catalogs/English")
  354.         (dest   "Locale:Catalogs/English")
  355.         (choices "AmiTEL.catalog")
  356.         (confirm)
  357.       )
  358.     )
  359.   )
  360. )
  361.  
  362. (complete 60)
  363.  
  364. ; Copy ARexx script files.
  365.  
  366. (if
  367.   (askbool
  368.     (prompt #rexx-file)
  369.     (help #rexx-help)
  370.     (default 1)
  371.   )
  372.  
  373.   (
  374.     (copyfiles
  375.       (prompt #sel-file)
  376.       (help @copyfiles-help)
  377.       (source "Rexx")
  378.       (dest   "REXX:")
  379.       (pattern "#?.amtl")
  380.       (confirm)
  381.     )
  382.   )
  383. )
  384.  
  385. (complete 70)
  386.  
  387. ; Copy 'XPRxxxxxx.library' files.
  388.  
  389. (if
  390.   (askbool
  391.     (prompt #xpr-lib)
  392.     (help #xpr-help)
  393.     (default 1)
  394.   )
  395.  
  396.   (if
  397.     (askbool
  398.       (prompt #020-lib)
  399.       (help #020-help)
  400.       (default 1)
  401.     )
  402.  
  403.     (
  404.       (copylib
  405.         (prompt #bbt-lib)
  406.         (help @copylib-help)
  407.         (source "Libs/xprbbtpro020.library")
  408.         (dest   "LIBS:")
  409.         (newname "xprbbtpro.library")
  410.         (confirm)
  411.       )
  412.  
  413.       (copylib
  414.         (prompt #moon-lib)
  415.         (help @copylib-help)
  416.         (source "Libs/xprmoondial020.library")
  417.         (dest   "LIBS:")
  418.         (newname "xprmoondial.library")
  419.         (confirm)
  420.       )
  421.     )
  422.  
  423.     (
  424.       (copylib
  425.         (prompt #bbt-lib)
  426.         (help @copylib-help)
  427.         (source "Libs/xprbbtpro.library")
  428.         (dest   "LIBS:")
  429.         (confirm)
  430.       )
  431.  
  432.       (copylib
  433.         (prompt #moon-lib)
  434.         (help @copylib-help)
  435.         (source "Libs/xprmoondial.library")
  436.         (dest   "LIBS:")
  437.         (confirm)
  438.       )
  439.     )
  440.   )
  441. )
  442.  
  443. (complete 80)
  444.  
  445. ; Copy 'ReqTools.library' and 'OwnDevUnit.library' file.
  446.  
  447. (copylib
  448.   (prompt #req-lib)
  449.   (help @copylib-help)
  450.   (source "Libs/reqtools.library")
  451.   (dest "LIBS:")
  452.   (confirm)
  453. )
  454.  
  455. (copylib
  456.   (prompt #odu-lib)
  457.   (help @copylib-help)
  458.   (source "Libs/OwnDevUnit.library")
  459.   (dest "LIBS:")
  460.   (confirm)
  461. )
  462.  
  463. (complete 90)
  464.  
  465. ; Update 'AmiTEL.phone' file.
  466.  
  467. (if
  468.   (exists (cat Path.Dest "/AmiTEL.phone"))
  469.   (message #update)
  470. )
  471.  
  472. (complete 100)
  473.  
  474. ; End of Program
  475.  
  476. (set @default-dest Path.Dest)
  477. (exit)
  478.